Setelah sebelumnya menggunakan Ubuntu, kali ini TISA coba di Windows.
Semua Sama, kecuali
Mulai dari bentuk, penerapan, ukuran label, hingga kode ZPL yang dipakai sama seperti pada tulisan sebelumnya.
Namun karena berbeda sistem operasi, maka ada penyesuaian pada skrip yang dibuat. Apabila sebelumnya menggunakan skrip bash, maka kali ini menggunakan skrip batch.
Skrip Batch/CMD
Berikut skrip batch hasil penyesuaian dari skrip bash sebelumnya.
@ECHO OFF
SETLOCAL EnableDelayedExpansion
:: CC0-1.0
:: https://creativecommons.org/publicdomain/zero/1.0/
:: -- VARIABEL -- ::
SET SUMBER_DATA=%1
SET FOLDER_TUJUAN=%2
:: -- PROSES -- ::
ECHO/
ECHO SEDANG MEMBUAT LABEL
ECHO/
:: Membaca sumber data.
FOR /F "tokens=1,2 delims=;" %%A in (%SUMBER_DATA%) DO (
:: Info.
SET NOMOR_SERI=%%A
SET JUDUL_BUKU=%%B
:: Buat ZPL.
ECHO Label Diproses: !NOMOR_SERI!
(
ECHO ^^XA
ECHO ^^PW479
ECHO ^^^^FO240,20^^^^AJ,18^^^^FD!JUDUL_BUKU!^^^^FS
ECHO ^^^^FO240,45^^^^A0,58^^^^FD!NOMOR_SERI!^^^^FS
ECHO ^^^^FO240,100^^^^BQN,2,5,Q,7^^^^FDQA,!NOMOR_SERI!^^^^FS
ECHO ^^^^FO130,40^^^^BY2,3,10^^^^BCR,40,Y,N,N,A^^^^FD!NOMOR_SERI!^^^^FS
ECHO ^^XZ
) > %cd%\%FOLDER_TUJUAN%\!NOMOR_SERI!.zpl
)
ECHO/
ECHO SELESAI
ENDLOCAL
Simpan skrip tersebut dengan nama skrip.cmd atau apalah.
Membuat Label
Pertama, siapkan lebih dulu data eksemplar yang hendak dibuatkan label. Nomor dan judul dipisahkan tanda titik koma. Disimpan dengan nama file misalnya data.csv. Contohnya seperti ini.
20241001;PJS 8 - KURMER
20241002;PJS 8 - KURMER
20241003;PJS 8 - KURMER
20241004;PJS 8 - KURMER
20241005;PJS 8 - KURMER
20241006;PJS 8 - KURMER
20241007;PJS 8 - KURMER
20241008;PJS 8 - KURMER
20241009;PJS 8 - KURMER
20241010;PJS 8 - KURMER
20241011;IPA 8 - KURMER
20241012;IPA 8 - KURMER
20241013;IPA 8 - KURMER
20241014;IPA 8 - KURMER
20241015;IPA 8 - KURMER
20241016;IPA 8 - KURMER
20241017;IPA 8 - KURMER
20241018;IPA 8 - KURMER
20241019;IPA 8 - KURMER
20241020;IPA 8 - KURMER
Kedua, siapkan folder hasil pembuatan label. Pastikan foldernya masih kosong, karena nanti akan diisi banyak sekali file.
Ketiga, buka Command Prompt lalu pindah ke direktori skrip yang sudah dibuat tersebut. Dalam contoh TISA, lokasinya berada di:
C:\Users\TISA\Documents\label_buku, sehingga perintah yang diketik pada Command Prompt sebagai berikut.
cd C:\Users\TISA\Documents\label_buku
Keempat, siap diproses. Ketikkan perintah berikut.
skrip.cmd data.csv folder_hasil
Posisi skrip.cmd, data.csv, dan folder_hasil tidak boleh terbalik dan harus di dalam folder yang sama.
Instalasi Printer
XP-D4601B juga tidak memerlukan driver tambahan ketika dipasang pada Windows (terutama Windows 10). Pastikan saja modelnya Generic / Text Only dan opsi berbaginya diaktifkan.
Mencetak
Pertama, masuk ke folder hasil pembuatan label.
cd folder_hasil
Kedua, mulai mencetak dengan pola perintah berikut.
PRINT /D:"\\%COMPUTERNAME%\{nama printer label}" {nama file ZPL}
Misalnya, hanya mencetak satu label.
PRINT /D:"\\%COMPUTERNAME%\XP-D4601B" 20241005.zpl
Jika hendak mencetak label untuk nomor-nomor tertentu, misalnya 20241001, 20241008, dan 20241012, dapat menggunakan perintah berikut.
PRINT /D:"\\%COMPUTERNAME%\XP-D4601B" 20241001.zpl 20241008.zpl 20241012.zpl
Jika hendak mencetak label untuk nomor seri 20241001 sampai 20241009, dapat menggunakan perintah ini.
PRINT /D:"\\%COMPUTERNAME%\XP-D4601B" 2024100*
Untuk mencetak label dari nomor 20241010 sampai 20241019, perintahnya seperti ini.
PRINT /D:"\\%COMPUTERNAME%\XP-D4601B" 2024101*
Jika hendak mencetak semua label sekaligus, gunakan perintah ini.
PRINT /D:"\\%COMPUTERNAME%\XP-D4601B" *.zpl
Sebaiknya, jangan gunakan perintah tersebut apabila label mencapai ratusan bahkan lebih.
Selamat mencoba.